81 lines
2.2 KiB
QML
81 lines
2.2 KiB
QML
import QtQuick
|
|
import Quickshell
|
|
import "." as M
|
|
import "../services" as S
|
|
import "../applets" as C
|
|
|
|
M.BarSection {
|
|
id: root
|
|
spacing: Math.max(1, S.Theme.moduleSpacing - 2)
|
|
tooltip: ""
|
|
|
|
property int percent: S.SystemStats.memPercent
|
|
property real usedGb: S.SystemStats.memUsedGb
|
|
property real totalGb: S.SystemStats.memTotalGb
|
|
property real availGb: S.SystemStats.memAvailGb
|
|
property real cachedGb: S.SystemStats.memCachedGb
|
|
property real buffersGb: S.SystemStats.memBuffersGb
|
|
|
|
property bool _pinned: false
|
|
readonly property bool _anyHover: root._hovered || hoverPanel.panelHovered
|
|
readonly property bool _showPanel: _anyHover || _pinned
|
|
|
|
property M.ProcessList _procs: M.ProcessList {
|
|
sortBy: "mem"
|
|
active: root._showPanel
|
|
onProcessesChanged: hoverPanel.keepOpen(300)
|
|
}
|
|
|
|
on_AnyHoverChanged: {
|
|
if (_anyHover)
|
|
_unpinTimer.stop();
|
|
else if (_pinned)
|
|
_unpinTimer.start();
|
|
}
|
|
|
|
Timer {
|
|
id: _unpinTimer
|
|
interval: 500
|
|
onTriggered: root._pinned = false
|
|
}
|
|
|
|
M.BarIcon {
|
|
icon: "\uEFC5"
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
TapHandler {
|
|
onTapped: root._pinned = !root._pinned
|
|
}
|
|
}
|
|
M.BarLabel {
|
|
label: root.percent + "%"
|
|
minText: "100%"
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
TapHandler {
|
|
onTapped: root._pinned = !root._pinned
|
|
}
|
|
}
|
|
|
|
M.HoverPanel {
|
|
id: hoverPanel
|
|
showPanel: root._showPanel
|
|
screen: QsWindow.window?.screen ?? null
|
|
anchorItem: root
|
|
accentColor: root.accentColor
|
|
panelNamespace: "nova-memory"
|
|
panelTitle: "Memory"
|
|
contentWidth: 240
|
|
|
|
C.MemoryApplet {
|
|
width: hoverPanel.contentWidth
|
|
percent: root.percent
|
|
usedGb: root.usedGb
|
|
totalGb: root.totalGb
|
|
availGb: root.availGb
|
|
cachedGb: root.cachedGb
|
|
buffersGb: root.buffersGb
|
|
processes: root._procs.processes
|
|
accentColor: root.accentColor
|
|
active: root._showPanel
|
|
}
|
|
}
|
|
}
|