124 lines
3.1 KiB
QML
124 lines
3.1 KiB
QML
import QtQuick
|
|
import Quickshell
|
|
import Quickshell.Io
|
|
import "." as M
|
|
import "../services" as S
|
|
import "../applets" as C
|
|
|
|
M.BarSection {
|
|
id: root
|
|
spacing: S.Theme.moduleSpacing
|
|
opacity: S.Modules.backlight.enable && percent > 0 ? 1 : 0
|
|
visible: opacity > 0
|
|
tooltip: ""
|
|
|
|
property int percent: 0
|
|
property bool _osdActive: false
|
|
property bool _percentInit: false
|
|
readonly property bool _showPanel: root._hovered || hoverPanel.panelHovered || _osdActive
|
|
|
|
onPercentChanged: {
|
|
if (!_percentInit) {
|
|
_percentInit = true;
|
|
return;
|
|
}
|
|
if (percent > 0)
|
|
_flashPanel();
|
|
}
|
|
|
|
function _flashPanel() {
|
|
_osdActive = true;
|
|
_osdTimer.restart();
|
|
}
|
|
|
|
Timer {
|
|
id: _osdTimer
|
|
interval: 1500
|
|
onTriggered: root._osdActive = false
|
|
}
|
|
|
|
Process {
|
|
id: adjProc
|
|
property string cmd: ""
|
|
command: ["sh", "-c", cmd]
|
|
onRunningChanged: if (!running && cmd !== "")
|
|
current.reload()
|
|
}
|
|
|
|
function adjust(delta) {
|
|
const step = S.Modules.backlight.step || 5;
|
|
adjProc.cmd = delta > 0 ? "light -A " + step : "light -U " + step;
|
|
adjProc.running = true;
|
|
}
|
|
|
|
function setPercent(pct) {
|
|
adjProc.cmd = "light -S " + Math.round(Math.max(0, Math.min(100, pct)));
|
|
adjProc.running = true;
|
|
}
|
|
|
|
property string _blDev: ""
|
|
Process {
|
|
id: detectBl
|
|
running: true
|
|
command: ["sh", "-c", "ls /sys/class/backlight/ 2>/dev/null | head -1"]
|
|
stdout: StdioCollector {
|
|
onStreamFinished: {
|
|
const dev = text.trim();
|
|
if (dev)
|
|
root._blDev = "/sys/class/backlight/" + dev;
|
|
}
|
|
}
|
|
}
|
|
|
|
FileView {
|
|
id: current
|
|
path: root._blDev ? root._blDev + "/brightness" : ""
|
|
watchChanges: true
|
|
onFileChanged: reload()
|
|
onLoaded: root._update()
|
|
}
|
|
FileView {
|
|
id: max
|
|
path: root._blDev ? root._blDev + "/max_brightness" : ""
|
|
onLoaded: root._update()
|
|
}
|
|
|
|
function _update() {
|
|
const c = parseInt(current.text());
|
|
const m = parseInt(max.text());
|
|
if (m > 0)
|
|
root.percent = Math.round((c / m) * 100);
|
|
}
|
|
|
|
M.BarIcon {
|
|
icon: "\uF185"
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
}
|
|
M.BarLabel {
|
|
label: root.percent + "%"
|
|
minText: "100%"
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
}
|
|
|
|
WheelHandler {
|
|
onWheel: event => root.adjust(event.angleDelta.y)
|
|
}
|
|
|
|
M.HoverPanel {
|
|
id: hoverPanel
|
|
showPanel: root._showPanel
|
|
screen: QsWindow.window?.screen ?? null
|
|
anchorItem: root
|
|
accentColor: root.accentColor
|
|
panelNamespace: "nova-backlight"
|
|
panelTitle: "Brightness"
|
|
contentWidth: 200
|
|
|
|
C.BacklightApplet {
|
|
width: parent.width
|
|
percent: root.percent
|
|
accentColor: root.accentColor
|
|
onSetPercent: pct => root.setPercent(pct)
|
|
}
|
|
}
|
|
}
|