import QtQuick
import QtQuick.Effects
import Quickshell
import Quickshell.Widgets
import "." as M

M.BarSection {
    id: root
    spacing: M.Theme.moduleSpacing
    visible: M.Modules.windowTitle.enable && M.NiriIpc.available && M.NiriIpc.focusedTitle !== ""

    tooltip: M.NiriIpc.focusedAppId ? M.NiriIpc.focusedAppId + "\n" + M.NiriIpc.focusedTitle : M.NiriIpc.focusedTitle

    readonly property string _iconSource: {
        if (!M.NiriIpc.focusedAppId)
            return "";
        const entry = DesktopEntries.heuristicLookup(M.NiriIpc.focusedAppId);
        return entry ? Quickshell.iconPath(entry.icon) : "";
    }

    IconImage {
        visible: root._iconSource !== ""
        source: root._iconSource
        implicitSize: M.Theme.fontSize + 2
        anchors.verticalCenter: parent.verticalCenter
        layer.enabled: true
        layer.effect: MultiEffect {
            colorization: 1.0
            colorizationColor: root.accentColor
        }
    }

    M.BarLabel {
        label: M.NiriIpc.focusedTitle
        color: root.accentColor
        elide: Text.ElideRight
        anchors.verticalCenter: parent.verticalCenter
    }
}