import QtQuick
import Quickshell
import "." as M
import "../services" as S
import "../applets" as C

M.PinnableSection {
    id: root
    spacing: S.Theme.moduleSpacing
    opacity: S.Modules.bluetooth.enable && S.BluetoothService.state !== "unavailable" ? 1 : 0
    visible: opacity > 0
    _panelHovered: hoverPanel.panelHovered

    M.BarIcon {
        icon: "\uF294"
        color: S.BluetoothService.state === "off" ? S.Theme.base04 : root.accentColor
        anchors.verticalCenter: parent.verticalCenter
        TapHandler {
            onTapped: root._pinned = !root._pinned
        }
    }
    M.BarLabel {
        visible: S.BluetoothService.state === "connected"
        label: S.BluetoothService.device + (S.BluetoothService.batteryPct >= 0 ? " " + S.BluetoothService.batteryPct + "%" : "")
        anchors.verticalCenter: parent.verticalCenter
        TapHandler {
            onTapped: root._pinned = !root._pinned
        }
    }

    Connections {
        target: S.BluetoothService
        function onDevicesChanged() {
            hoverPanel.keepOpen(500);
        }
    }

    M.HoverPanel {
        id: hoverPanel
        showPanel: root._showPanel
        screen: QsWindow.window?.screen ?? null
        anchorItem: root
        accentColor: root.accentColor
        panelNamespace: "nova-bluetooth"
        panelTitle: "Bluetooth"
        contentWidth: 250
        titleActionsComponent: Component {
            Item {
                width: 20
                height: 20

                Text {
                    anchors.centerIn: parent
                    text: "\uF011"
                    color: S.BluetoothService.enabled ? hoverPanel.accentColor : S.Theme.base04
                    font.pixelSize: S.Theme.fontSize
                    font.family: S.Theme.iconFontFamily

                    Behavior on color {
                        ColorAnimation {
                            duration: 100
                        }
                    }
                }

                HoverHandler {
                    cursorShape: Qt.PointingHandCursor
                }

                TapHandler {
                    onTapped: S.BluetoothService.setPower(!S.BluetoothService.enabled)
                }
            }
        }

        onVisibleChanged: if (visible)
            S.BluetoothService.refresh()

        C.BluetoothApplet {
            width: hoverPanel.contentWidth
            accentColor: root.accentColor
        }
    }
}