import QtQuick
import Quickshell.Services.Pipewire
import "." as M

M.BarSection {
    id: root
    spacing: M.Theme.moduleSpacing
    tooltip: (root.sink?.description ?? root.sink?.name ?? "Unknown sink") + "\nVolume: " + Math.round(root.volume * 100) + "%" + (root.muted ? "\nMuted" : "")

    PwObjectTracker {
        objects: [Pipewire.defaultAudioSink]
    }

    readonly property var sink: Pipewire.defaultAudioSink
    readonly property real volume: sink?.audio?.volume ?? 0
    readonly property bool muted: sink?.audio?.muted ?? false

    onVolumeChanged: M.OsdState.show(volume, root.muted ? "\uF026" : (volume > 0.5 ? "\uF028" : "\uF027"))
    onMutedChanged: M.OsdState.show(volume, root.muted ? "\uF026" : (volume > 0.5 ? "\uF028" : "\uF027"))

    M.BarIcon {
        icon: root.muted ? "\uF026" : (root.volume > 0.5 ? "\uF028" : (root.volume > 0 ? "\uF027" : "\uF026"))
        color: root.muted ? M.Theme.base04 : M.Theme.base0E
        anchors.verticalCenter: parent.verticalCenter
    }
    M.BarLabel {
        label: Math.round(root.volume * 100) + "%"
        color: root.muted ? M.Theme.base04 : M.Theme.base0E
        anchors.verticalCenter: parent.verticalCenter
    }

    TapHandler {
        onTapped: if (root.sink?.audio)
            root.sink.audio.muted = !root.sink.audio.muted
    }

    WheelHandler {
        onWheel: event => {
            if (!root.sink?.audio)
                return;
            root.sink.audio.volume = Math.max(0, root.sink.audio.volume + (event.angleDelta.y > 0 ? 0.05 : -0.05));
        }
    }
}