import QtQuick
import QtQuick.Effects
import Quickshell
import "." as M

Row {
    id: root
    property string tooltip: ""
    property bool _hovered: false
    property color accentColor: parent?.accentColor ?? M.Theme.base05

    Behavior on opacity {
        NumberAnimation {
            duration: 150
        }
    }

    layer.enabled: _hovered
    layer.effect: MultiEffect {
        shadowEnabled: true
        shadowColor: M.Theme.base05
        shadowBlur: 0.5
        shadowVerticalOffset: 0
        shadowHorizontalOffset: 0
    }

    HoverHandler {
        onHoveredChanged: {
            root._hovered = hovered;
            if (hovered && root.tooltip !== "") {
                M.FlyoutState.text = root.tooltip;
                M.FlyoutState.itemX = root.mapToGlobal(root.width / 2, 0).x - (QsWindow.window?.screen?.x ?? 0);
                M.FlyoutState.screen = QsWindow.window?.screen ?? null;
                M.FlyoutState.visible = true;
            } else if (!hovered && root.tooltip !== "") {
                M.FlyoutState.visible = false;
            }
        }
    }
}