import QtQuick
import Quickshell
import "." as M
import "../services" as S
import "../applets" as C

M.BarSection {
    id: root
    spacing: S.Theme.moduleSpacing
    tooltip: ""
    visible: S.Modules.weather.enable && S.WeatherService.available

    property bool _pinned: false
    readonly property bool _anyHover: root._hovered || hoverPanel.panelHovered
    readonly property bool _showPanel: _anyHover || _pinned

    on_AnyHoverChanged: {
        if (_anyHover)
            _unpinTimer.stop();
        else if (_pinned)
            _unpinTimer.start();
    }

    Timer {
        id: _unpinTimer
        interval: 500
        onTriggered: root._pinned = false
    }

    M.BarIcon {
        icon: S.WeatherService.icon
        anchors.verticalCenter: parent.verticalCenter
        TapHandler {
            onTapped: root._pinned = !root._pinned
        }
    }

    M.HoverPanel {
        id: hoverPanel
        showPanel: root._showPanel
        screen: QsWindow.window?.screen ?? null
        anchorItem: root
        accentColor: root.accentColor
        panelNamespace: "nova-weather"
        panelTitle: "Weather"
        contentWidth: 280

        C.WeatherApplet {
            width: hoverPanel.contentWidth
            accentColor: root.accentColor
        }
    }
}