import QtQuick
import Quickshell
import "." as M
import "../services" as S
import "../applets" as C

M.BarSection {
    id: root
    spacing: S.Theme.moduleSpacing
    tooltip: ""

    SystemClock {
        id: clock
        precision: SystemClock.Seconds
    }

    property bool _pinned: false
    readonly property bool _anyHover: root._hovered || hoverPanel.panelHovered
    readonly property bool _showPanel: _anyHover || _pinned

    on_AnyHoverChanged: {
        if (_anyHover)
            _unpinTimer.stop();
        else if (_pinned)
            _unpinTimer.start();
    }

    Timer {
        id: _unpinTimer
        interval: 500
        onTriggered: root._pinned = false
    }

    M.BarLabel {
        font.pixelSize: S.Theme.fontSize + 1
        label: Qt.formatDateTime(clock.date, "ddd, dd. MMM  HH:mm")
        minText: "Wed, 00. Sep  00:00"
        anchors.verticalCenter: parent.verticalCenter
        TapHandler {
            onTapped: root._pinned = !root._pinned
        }
    }

    M.HoverPanel {
        id: hoverPanel
        showPanel: root._showPanel
        screen: QsWindow.window?.screen ?? null
        anchorItem: root
        accentColor: root.accentColor
        panelNamespace: "nova-clock"
        panelTitle: Qt.formatTime(clock.date, "HH:mm:ss")
        contentWidth: 220

        C.ClockApplet {
            width: hoverPanel.contentWidth
            accentColor: root.accentColor
            currentDate: clock.date
        }
    }
}