import QtQuick
import Quickshell
import "." as M
import "../services" as S
import "../applets" as C

M.BarModule {
    id: root
    spacing: S.Theme.moduleSpacing
    tooltip: {
        if (state === "wifi")
            return "Wi-Fi: " + S.NetworkService.essid;
        if (state === "eth")
            return "Ethernet: connected";
        if (state === "linked")
            return "Network: linked";
        return "Network: disconnected";
    }
    panelNamespace: "nova-network"
    panelTitle: "Wi-Fi"
    panelContentWidth: 250
    titleActionsComponent: Component {
        Item {
            width: 20
            height: 20

            Text {
                anchors.centerIn: parent
                text: "\uF011"
                color: S.NetworkService.wifiEnabled ? root.accentColor : S.Theme.base04
                font.pixelSize: S.Theme.fontSize
                font.family: S.Theme.iconFontFamily

                Behavior on color {
                    ColorAnimation {
                        duration: 100
                    }
                }
            }

            HoverHandler {
                cursorShape: Qt.PointingHandCursor
            }

            TapHandler {
                onTapped: S.NetworkService.setWifi(!S.NetworkService.wifiEnabled)
            }
        }
    }
    panelComponent: Component {
        C.NetworkApplet {
            width: parent.width
            accentColor: root.accentColor
        }
    }

    readonly property string state: S.NetworkService.state

    on_ShowPanelChanged: if (_showPanel)
        S.NetworkService.refresh()

    Connections {
        target: S.NetworkService
        function onNetworksChanged() {
            root.keepPanelOpen(500);
        }
    }

    M.BarIcon {
        icon: {
            if (root.state === "wifi")
                return "\uF1EB";
            if (root.state === "eth")
                return "\uDB80\uDE00";
            if (root.state === "linked")
                return "\uDB85\uDE16";
            return "\uDB82\uDCFD";
        }
        color: root.state === "disconnected" ? S.Theme.base08 : root.accentColor
        anchors.verticalCenter: parent.verticalCenter
    }
    M.BarLabel {
        visible: root.state === "wifi"
        label: S.NetworkService.essid
        color: root.state === "disconnected" ? S.Theme.base08 : root.accentColor
        anchors.verticalCenter: parent.verticalCenter
    }
}