rename Flyout/FlyoutState to Tooltip/TooltipState, improve qmllint check script

2026-04-24 22:33:26 +02:00 · 2026-04-24 22:33:26 +02:00 · e5e15f82fb
commit e5e15f82fb
parent 0c955f93f8
12 changed files with 82 additions and 57 deletions
--- a/shell/modules/Tooltip.qml
+++ b/shell/modules/Tooltip.qml
@ -0,0 +1,102 @@
+import QtQuick
+import Quickshell
+import Quickshell.Wayland
+import "." as M
+import "../services" as S
+
+PanelWindow {
+    id: root
+
+    required property var screen
+
+    visible: _winVisible
+    color: "transparent"
+
+    property bool _winVisible: false
+    property bool _shown: M.TooltipState.visible && M.TooltipState.screen === root.screen
+
+    on_ShownChanged: {
+        if (_shown) {
+            _winVisible = true;
+            hideAnim.stop();
+            showAnim.start();
+        } else {
+            showAnim.stop();
+            hideAnim.start();
+        }
+    }
+
+    WlrLayershell.layer: WlrLayer.Overlay
+    WlrLayershell.exclusiveZone: 0
+    WlrLayershell.namespace: "nova-flyout"
+
+    anchors.top: true
+    anchors.left: true
+
+    margins.top: 0
+    margins.left: Math.max(0, Math.min(Math.round(M.TooltipState.itemX - implicitWidth / 2), screen.width - implicitWidth))
+
+    implicitWidth: label.implicitWidth + S.Theme.barPadding * 2
+    implicitHeight: label.implicitHeight + S.Theme.barPadding * 2
+
+    ParallelAnimation {
+        id: showAnim
+        NumberAnimation {
+            target: content
+            property: "opacity"
+            to: 1
+            duration: 120
+            easing.type: Easing.OutCubic
+        }
+        NumberAnimation {
+            target: content
+            property: "y"
+            to: 0
+            duration: 150
+            easing.type: Easing.OutCubic
+        }
+    }
+
+    ParallelAnimation {
+        id: hideAnim
+        NumberAnimation {
+            target: content
+            property: "opacity"
+            to: 0
+            duration: 150
+            easing.type: Easing.InCubic
+        }
+        NumberAnimation {
+            target: content
+            property: "y"
+            to: -content.height
+            duration: 150
+            easing.type: Easing.InCubic
+        }
+        onFinished: root._winVisible = false
+    }
+
+    Item {
+        id: content
+        anchors.left: parent.left
+        anchors.right: parent.right
+        height: root.implicitHeight
+        opacity: 0
+        y: -height
+
+        M.PopupBackground {
+            anchors.fill: parent
+            accentColor: M.TooltipState.accentColor
+        }
+
+        Text {
+            id: label
+            anchors.centerIn: parent
+            text: M.TooltipState.text.replace(/\n/g, "<br>")
+            textFormat: Text.RichText
+            color: S.Theme.base05
+            font.pixelSize: S.Theme.fontSize
+            font.family: S.Theme.fontFamily
+        }
+    }
+}