reorganize repo: move shell sources into shell/, test scripts into test/

2026-04-17 18:29:40 +02:00 · 2026-04-17 18:29:40 +02:00 · d6cd2f173a
commit d6cd2f173a
parent 344c1f8512
60 changed files with 2 additions and 2 deletions
--- a/shell/modules/PowerMenu.qml
+++ b/shell/modules/PowerMenu.qml
@ -0,0 +1,100 @@
+import QtQuick
+import Quickshell
+import "." as M
+
+M.HoverPanel {
+    id: menuWindow
+
+    popupMode: true
+    contentWidth: 180
+
+    signal runCommand(var cmd)
+
+    readonly property bool _isNiri: Quickshell.env("NIRI_SOCKET") !== ""
+
+    function _run(cmd) {
+        runCommand(cmd);
+        dismiss();
+    }
+
+    Repeater {
+        model: [
+            {
+                label: "Lock",
+                icon: "\uF023",
+                cmd: ["loginctl", "lock-session"],
+                color: M.Theme.base0D
+            },
+            {
+                label: "Suspend",
+                icon: "\uF186",
+                cmd: ["systemctl", "suspend"],
+                color: M.Theme.base0E
+            },
+            {
+                label: "Logout",
+                icon: "\uF2F5",
+                cmd: menuWindow._isNiri ? ["niri", "msg", "action", "quit"] : ["loginctl", "terminate-user", ""],
+                color: M.Theme.base0A
+            },
+            {
+                label: "Reboot",
+                icon: "\uF021",
+                cmd: ["systemctl", "reboot"],
+                color: M.Theme.base09
+            },
+            {
+                label: "Shutdown",
+                icon: "\uF011",
+                cmd: ["systemctl", "poweroff"],
+                color: M.Theme.base08
+            }
+        ]
+
+        delegate: Item {
+            id: entry
+
+            required property var modelData
+            required property int index
+
+            width: menuWindow.contentWidth
+            height: 32
+
+            Rectangle {
+                anchors.fill: parent
+                anchors.leftMargin: 4
+                anchors.rightMargin: 4
+                color: entryArea.containsMouse ? M.Theme.base02 : "transparent"
+                radius: M.Theme.radius
+            }
+
+            Text {
+                id: entryIcon
+                anchors.verticalCenter: parent.verticalCenter
+                anchors.left: parent.left
+                anchors.leftMargin: 12
+                text: entry.modelData.icon
+                color: entry.modelData.color
+                font.pixelSize: M.Theme.fontSize + 1
+                font.family: M.Theme.iconFontFamily
+            }
+
+            Text {
+                anchors.verticalCenter: parent.verticalCenter
+                anchors.left: entryIcon.right
+                anchors.leftMargin: 10
+                text: entry.modelData.label
+                color: M.Theme.base05
+                font.pixelSize: M.Theme.fontSize
+                font.family: M.Theme.fontFamily
+            }
+
+            MouseArea {
+                id: entryArea
+                anchors.fill: parent
+                hoverEnabled: true
+                onClicked: menuWindow._run(entry.modelData.cmd)
+            }
+        }
+    }
+}