reorganize repo: move shell sources into shell/, test scripts into test/

2026-04-17 18:29:40 +02:00 · 2026-04-17 18:29:40 +02:00 · d6cd2f173a
commit d6cd2f173a
parent 344c1f8512
60 changed files with 2 additions and 2 deletions
--- a/shell/modules/Flyout.qml
+++ b/shell/modules/Flyout.qml
@ -0,0 +1,101 @@
+import QtQuick
+import Quickshell
+import Quickshell.Wayland
+import "." as M
+
+PanelWindow {
+    id: root
+
+    required property var screen
+
+    visible: _winVisible
+    color: "transparent"
+
+    property bool _winVisible: false
+    property bool _shown: M.FlyoutState.visible && M.FlyoutState.screen === root.screen
+
+    on_ShownChanged: {
+        if (_shown) {
+            _winVisible = true;
+            hideAnim.stop();
+            showAnim.start();
+        } else {
+            showAnim.stop();
+            hideAnim.start();
+        }
+    }
+
+    WlrLayershell.layer: WlrLayer.Overlay
+    WlrLayershell.exclusiveZone: 0
+    WlrLayershell.namespace: "nova-flyout"
+
+    anchors.top: true
+    anchors.left: true
+
+    margins.top: 0
+    margins.left: Math.max(0, Math.min(Math.round(M.FlyoutState.itemX - implicitWidth / 2), screen.width - implicitWidth))
+
+    implicitWidth: label.implicitWidth + M.Theme.barPadding * 2
+    implicitHeight: label.implicitHeight + M.Theme.barPadding * 2
+
+    ParallelAnimation {
+        id: showAnim
+        NumberAnimation {
+            target: content
+            property: "opacity"
+            to: 1
+            duration: 120
+            easing.type: Easing.OutCubic
+        }
+        NumberAnimation {
+            target: content
+            property: "y"
+            to: 0
+            duration: 150
+            easing.type: Easing.OutCubic
+        }
+    }
+
+    ParallelAnimation {
+        id: hideAnim
+        NumberAnimation {
+            target: content
+            property: "opacity"
+            to: 0
+            duration: 150
+            easing.type: Easing.InCubic
+        }
+        NumberAnimation {
+            target: content
+            property: "y"
+            to: -content.height
+            duration: 150
+            easing.type: Easing.InCubic
+        }
+        onFinished: root._winVisible = false
+    }
+
+    Item {
+        id: content
+        anchors.left: parent.left
+        anchors.right: parent.right
+        height: root.implicitHeight
+        opacity: 0
+        y: -height
+
+        M.PopupBackground {
+            anchors.fill: parent
+            accentColor: M.FlyoutState.accentColor
+        }
+
+        Text {
+            id: label
+            anchors.centerIn: parent
+            text: M.FlyoutState.text.replace(/\n/g, "<br>")
+            textFormat: Text.RichText
+            color: M.Theme.base05
+            font.pixelSize: M.Theme.fontSize
+            font.family: M.Theme.fontFamily
+        }
+    }
+}