reorganize repo: move shell sources into shell/, test scripts into test/

2026-04-17 18:29:40 +02:00 · 2026-04-17 18:29:40 +02:00 · d6cd2f173a
commit d6cd2f173a
parent 344c1f8512
60 changed files with 2 additions and 2 deletions
--- a/shell/modules/Backlight.qml
+++ b/shell/modules/Backlight.qml
@ -0,0 +1,186 @@
+import QtQuick
+import Quickshell
+import Quickshell.Io
+import "." as M
+
+M.BarSection {
+    id: root
+    spacing: M.Theme.moduleSpacing
+    opacity: M.Modules.backlight.enable && percent > 0 ? 1 : 0
+    visible: opacity > 0
+    tooltip: ""
+
+    property int percent: 0
+    property bool _osdActive: false
+    property bool _percentInit: false
+    readonly property bool _showPanel: root._hovered || hoverPanel.panelHovered || _osdActive
+
+    onPercentChanged: {
+        if (!_percentInit) {
+            _percentInit = true;
+            return;
+        }
+        if (percent > 0)
+            _flashPanel();
+    }
+
+    function _flashPanel() {
+        _osdActive = true;
+        _osdTimer.restart();
+    }
+
+    Timer {
+        id: _osdTimer
+        interval: 1500
+        onTriggered: root._osdActive = false
+    }
+
+    Process {
+        id: adjProc
+        property string cmd: ""
+        command: ["sh", "-c", cmd]
+        onRunningChanged: if (!running && cmd !== "")
+            current.reload()
+    }
+
+    function adjust(delta) {
+        const step = M.Modules.backlight.step || 5;
+        adjProc.cmd = delta > 0 ? "light -A " + step : "light -U " + step;
+        adjProc.running = true;
+    }
+
+    function setPercent(pct) {
+        adjProc.cmd = "light -S " + Math.round(Math.max(0, Math.min(100, pct)));
+        adjProc.running = true;
+    }
+
+    property string _blDev: ""
+    Process {
+        id: detectBl
+        running: true
+        command: ["sh", "-c", "ls /sys/class/backlight/ 2>/dev/null | head -1"]
+        stdout: StdioCollector {
+            onStreamFinished: {
+                const dev = text.trim();
+                if (dev)
+                    root._blDev = "/sys/class/backlight/" + dev;
+            }
+        }
+    }
+
+    FileView {
+        id: current
+        path: root._blDev ? root._blDev + "/brightness" : ""
+        watchChanges: true
+        onFileChanged: reload()
+        onLoaded: root._update()
+    }
+    FileView {
+        id: max
+        path: root._blDev ? root._blDev + "/max_brightness" : ""
+        onLoaded: root._update()
+    }
+
+    function _update() {
+        const c = parseInt(current.text());
+        const m = parseInt(max.text());
+        if (m > 0)
+            root.percent = Math.round((c / m) * 100);
+    }
+
+    M.BarIcon {
+        icon: "\uF185"
+        anchors.verticalCenter: parent.verticalCenter
+    }
+    M.BarLabel {
+        label: root.percent + "%"
+        minText: "100%"
+        anchors.verticalCenter: parent.verticalCenter
+    }
+
+    WheelHandler {
+        onWheel: event => root.adjust(event.angleDelta.y)
+    }
+
+    M.HoverPanel {
+        id: hoverPanel
+        showPanel: root._showPanel
+        screen: QsWindow.window?.screen ?? null
+        anchorItem: root
+        accentColor: root.accentColor
+        panelNamespace: "nova-backlight"
+        panelTitle: "Brightness"
+        contentWidth: 200
+
+        Item {
+            width: parent.width
+            height: 36
+
+            Text {
+                id: blIcon
+                anchors.left: parent.left
+                anchors.leftMargin: 12
+                anchors.verticalCenter: parent.verticalCenter
+                text: "\uF185"
+                color: root.accentColor
+                font.pixelSize: M.Theme.fontSize + 2
+                font.family: M.Theme.iconFontFamily
+            }
+
+            Item {
+                id: slider
+                anchors.left: blIcon.right
+                anchors.leftMargin: 8
+                anchors.right: blLabel.left
+                anchors.rightMargin: 8
+                anchors.verticalCenter: parent.verticalCenter
+                height: 6
+
+                Rectangle {
+                    anchors.fill: parent
+                    color: M.Theme.base02
+                    radius: 3
+                }
+
+                Rectangle {
+                    width: parent.width * root.percent / 100
+                    height: parent.height
+                    color: root.accentColor
+                    radius: 3
+
+                    Behavior on width {
+                        NumberAnimation {
+                            duration: 80
+                        }
+                    }
+                }
+
+                MouseArea {
+                    anchors.fill: parent
+                    anchors.margins: -6
+                    cursorShape: Qt.PointingHandCursor
+                    onPressed: mouse => _set(mouse)
+                    onPositionChanged: mouse => {
+                        if (pressed)
+                            _set(mouse);
+                    }
+                    function _set(mouse) {
+                        root.setPercent(mouse.x / slider.width * 100);
+                    }
+                }
+            }
+
+            Text {
+                id: blLabel
+                anchors.right: parent.right
+                anchors.rightMargin: 12
+                anchors.verticalCenter: parent.verticalCenter
+                text: root.percent + "%"
+                color: M.Theme.base05
+                font.pixelSize: M.Theme.fontSize
+                font.family: M.Theme.fontFamily
+                width: 30
+            }
+        }
+    }
+}