rename bar module files and qmldir types to *Module

shell/modules/DiskModule.qml

@@ -0,0 +1,66 @@
+import QtQuick
+import Quickshell
+import "." as M
+import "../services" as S
+import "../applets" as C
+
+M.BarSection {
+    id: root
+    spacing: Math.max(1, S.Theme.moduleSpacing - 2)
+    tooltip: ""
+
+    property var _mounts: S.SystemStats.diskMounts
+    property int _rootPct: S.SystemStats.diskRootPct
+
+    property bool _pinned: false
+    readonly property bool _anyHover: root._hovered || hoverPanel.panelHovered
+    readonly property bool _showPanel: _anyHover || _pinned
+
+    on_AnyHoverChanged: {
+        if (_anyHover)
+            _unpinTimer.stop();
+        else if (_pinned)
+            _unpinTimer.start();
+    }
+
+    Timer {
+        id: _unpinTimer
+        interval: 500
+        onTriggered: root._pinned = false
+    }
+
+    M.BarIcon {
+        icon: "\uF0C9"
+        anchors.verticalCenter: parent.verticalCenter
+        TapHandler {
+            cursorShape: Qt.PointingHandCursor
+            onTapped: root._pinned = !root._pinned
+        }
+    }
+    M.BarLabel {
+        label: root._rootPct + "%"
+        minText: "100%"
+        anchors.verticalCenter: parent.verticalCenter
+        TapHandler {
+            cursorShape: Qt.PointingHandCursor
+            onTapped: root._pinned = !root._pinned
+        }
+    }
+
+    M.HoverPanel {
+        id: hoverPanel
+        showPanel: root._showPanel
+        screen: QsWindow.window?.screen ?? null
+        anchorItem: root
+        accentColor: root.accentColor
+        panelNamespace: "nova-disk"
+        panelTitle: "Disk"
+        contentWidth: 260
+
+        C.DiskApplet {
+            width: hoverPanel.contentWidth
+            mounts: root._mounts
+            accentColor: root.accentColor
+        }
+    }
+}