vinzenz/nova-shell
0
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions

refactor: unified BarModule base component, click-to-open panels, remove pinning

Browse source
This commit is contained in:
Damocles 2026-04-25 11:52:20 +02:00
parent 034f0b6d85
commit 26476dc930
33 changed files with 273 additions and 517 deletions
Download patch file Download diff file Expand all files Collapse all files

226
shell/applets/PowerApplet.qml Normal file
View file

@ -0,0 +1,226 @@
import QtQuick
import Quickshell
import "../services" as S
Column {
id: root
required property color accentColor
signal runCommand(var cmd)
signal dismiss
readonly property bool _isNiri: Quickshell.env("NIRI_SOCKET") !== ""
property var _confirmItem: null
function _run(cmd) {
runCommand(cmd);
dismiss();
}
function _requestAction(item) {
if (item.confirm) {
_confirmItem = item;
} else {
_run(item.cmd);
}
}
function _cancelConfirm() {
_confirmItem = null;
}
// Normal menu entries
Column {
visible: !root._confirmItem
width: root.width
Repeater {
model: [
{
label: "Lock",
icon: "\uF023",
cmd: ["loginctl", "lock-session"],
color: S.Theme.base0D,
confirm: false
},
{
label: "Suspend",
icon: "\uF186",
cmd: ["systemctl", "suspend"],
color: S.Theme.base0E,
confirm: false
},
{
label: "Logout",
icon: "\uF2F5",
cmd: root._isNiri ? ["niri", "msg", "action", "quit"] : ["loginctl", "terminate-user", ""],
color: S.Theme.base0A,
confirm: false
},
{
label: "Reboot",
icon: "\uF021",
cmd: ["systemctl", "reboot"],
color: S.Theme.base09,
confirm: true
},
{
label: "Shutdown",
icon: "\uF011",
cmd: ["systemctl", "poweroff"],
color: S.Theme.base08,
confirm: true
}
]
delegate: Item {
id: entry
required property var modelData
required property int index
width: root.width
height: 32
Rectangle {
anchors.fill: parent
anchors.leftMargin: 4
anchors.rightMargin: 4
color: entryHover.hovered ? S.Theme.base02 : "transparent"
radius: S.Theme.radius
}
Text {
id: entryIcon
anchors.verticalCenter: parent.verticalCenter
anchors.left: parent.left
anchors.leftMargin: 12
text: entry.modelData.icon
color: entry.modelData.color
font.pixelSize: S.Theme.fontSize + 1
font.family: S.Theme.iconFontFamily
}
Text {
anchors.verticalCenter: parent.verticalCenter
anchors.left: entryIcon.right
anchors.leftMargin: 10
text: entry.modelData.label
color: S.Theme.base05
font.pixelSize: S.Theme.fontSize
font.family: S.Theme.fontFamily
}
HoverHandler {
id: entryHover
cursorShape: Qt.PointingHandCursor
}
TapHandler {
onTapped: root._requestAction(entry.modelData)
}
}
}
}
// Confirmation view
Column {
visible: !!root._confirmItem
width: root.width
spacing: 4
Item {
width: parent.width
height: 28
Text {
anchors.centerIn: parent
text: root._confirmItem ? root._confirmItem.label + "?" : ""
color: root._confirmItem ? root._confirmItem.color : S.Theme.base05
font.pixelSize: S.Theme.fontSize
font.family: S.Theme.fontFamily
font.bold: true
}
}
Row {
anchors.horizontalCenter: parent.horizontalCenter
spacing: 8
Item {
width: 72
height: 28
Rectangle {
anchors.fill: parent
color: cancelHover.hovered ? S.Theme.base02 : S.Theme.base01
radius: S.Theme.radius
border.width: 1
border.color: S.Theme.base03
}
Text {
anchors.centerIn: parent
text: "Cancel"
color: S.Theme.base05
font.pixelSize: S.Theme.fontSize
font.family: S.Theme.fontFamily
}
HoverHandler {
id: cancelHover
cursorShape: Qt.PointingHandCursor
}
TapHandler {
onTapped: root._cancelConfirm()
}
}
Item {
width: 72
height: 28
Rectangle {
anchors.fill: parent
color: {
if (!root._confirmItem)
return S.Theme.base02;
const c = root._confirmItem.color;
return confirmHover.hovered ? Qt.rgba(c.r, c.g, c.b, 0.3) : Qt.rgba(c.r, c.g, c.b, 0.15);
}
radius: S.Theme.radius
border.width: 1
border.color: root._confirmItem ? root._confirmItem.color : S.Theme.base03
}
Text {
anchors.centerIn: parent
text: "Confirm"
color: root._confirmItem ? root._confirmItem.color : S.Theme.base05
font.pixelSize: S.Theme.fontSize
font.family: S.Theme.fontFamily
font.bold: true
}
HoverHandler {
id: confirmHover
cursorShape: Qt.PointingHandCursor
}
TapHandler {
onTapped: {
if (root._confirmItem)
root._run(root._confirmItem.cmd);
}
}
}
}
Item {
width: 1
height: 4
}
}
}