flake: rust devshell

flake.nix

@@ -0,0 +1,69 @@
+{
+  description = "hyperhive — multi-Claude-Code-agent orchestration on nixos-containers";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
+    treefmt-nix = {
+      url = "github:numtide/treefmt-nix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+
+  outputs =
+    inputs@{
+      self,
+      nixpkgs,
+      treefmt-nix,
+    }:
+    let
+      inherit (nixpkgs) lib;
+      systems = [
+        "aarch64-linux"
+        "x86_64-linux"
+      ];
+      treefmt-config = {
+        projectRootFile = "flake.nix";
+        programs = {
+          keep-sorted.enable = true;
+          nixfmt.enable = true;
+          rustfmt.enable = true;
+        };
+      };
+      forAllSystems =
+        f:
+        lib.genAttrs systems (
+          system:
+          f rec {
+            inherit system;
+            pkgs = nixpkgs.legacyPackages.${system};
+            treefmt-eval = treefmt-nix.lib.evalModule pkgs treefmt-config;
+          }
+        );
+    in
+    {
+      devShells = forAllSystems (
+        { pkgs, ... }:
+        {
+          default = pkgs.mkShell {
+            packages = with pkgs; [
+              cargo
+              clippy
+              pkg-config
+              rust-analyzer
+              rustc
+              rustfmt
+            ];
+          };
+        }
+      );
+
+      formatter = forAllSystems ({ treefmt-eval, ... }: treefmt-eval.config.build.wrapper);
+
+      checks = forAllSystems (
+        { treefmt-eval, ... }:
+        {
+          formatting = treefmt-eval.config.build.check self;
+        }
+      );
+    };
+}