pragma ComponentBehavior: Bound

import QtQuick
import "../services" as S
import NovaStats as NS

Column {
    id: root

    required property color accentColor
    property bool active: true
    signal contentResized

    onHeightChanged: root.contentResized()

    // Local machine header + units
    SystemdMachineSection {
        width: root.width
        accentColor: root.accentColor
        machineName: ""
        title: S.SystemdService.hostname
        marker: "  this machine"
        systemState: S.SystemdService.systemState
        units: S.SystemdService.failedUnits
        startExpanded: true
    }

    // Containers
    Repeater {
        model: S.SystemdService.containers

        delegate: Column {
            id: _row
            required property var modelData
            width: root.width

            Separator {}

            SystemdMachineSection {
                width: _row.width
                accentColor: root.accentColor
                machineName: _row.modelData.name
                title: _row.modelData.name
                marker: ""
                systemState: _row.modelData.systemState ?? "unknown"
                units: _row.modelData.failedUnits ?? []
                startExpanded: (_row.modelData.failedUnits ?? []).length > 0
            }
        }
    }

    Item {
        width: 1
        height: 4
    }
}