extract NetworkApplet, fold NetworkMenu into NetworkModule with pin support

shell/applets/NetworkApplet.qml

@@ -0,0 +1,91 @@
+import QtQuick
+import "../services" as S
+
+Column {
+    id: root
+
+    required property color accentColor
+
+    Repeater {
+        model: S.NetworkService.networks
+
+        delegate: Item {
+            id: entry
+            required property var modelData
+            required property int index
+
+            width: root.width
+            height: 32
+
+            Rectangle {
+                anchors.fill: parent
+                anchors.leftMargin: 4
+                anchors.rightMargin: 4
+                color: entryHover.hovered ? S.Theme.base02 : "transparent"
+                radius: S.Theme.radius
+            }
+
+            Text {
+                id: netIcon
+                anchors.left: parent.left
+                anchors.leftMargin: 12
+                anchors.verticalCenter: parent.verticalCenter
+                text: entry.modelData.isWifi ? "\uF1EB" : "\uDB80\uDE00"
+                color: entry.modelData.active ? root.accentColor : S.Theme.base05
+                font.pixelSize: S.Theme.fontSize + 1
+                font.family: S.Theme.iconFontFamily
+            }
+
+            Text {
+                anchors.left: netIcon.right
+                anchors.leftMargin: 8
+                anchors.right: sigLabel.left
+                anchors.rightMargin: 4
+                anchors.verticalCenter: parent.verticalCenter
+                text: entry.modelData.name
+                color: entry.modelData.active ? root.accentColor : S.Theme.base05
+                font.pixelSize: S.Theme.fontSize
+                font.family: S.Theme.fontFamily
+                font.bold: entry.modelData.active
+                elide: Text.ElideRight
+            }
+
+            Text {
+                id: sigLabel
+                anchors.right: parent.right
+                anchors.rightMargin: 12
+                anchors.verticalCenter: parent.verticalCenter
+                text: entry.modelData.signal >= 0 ? entry.modelData.signal + "%" : ""
+                color: S.Theme.base04
+                font.pixelSize: S.Theme.fontSize - 1
+                font.family: S.Theme.fontFamily
+                width: entry.modelData.signal >= 0 ? implicitWidth : 0
+            }
+
+            HoverHandler {
+                id: entryHover
+                cursorShape: Qt.PointingHandCursor
+            }
+            TapHandler {
+                onTapped: {
+                    if (entry.modelData.active)
+                        S.NetworkService.disconnectNetwork(entry.modelData.uuid);
+                    else
+                        S.NetworkService.connectNetwork(entry.modelData.uuid);
+                }
+            }
+        }
+    }
+
+    Text {
+        visible: S.NetworkService.networks.length === 0
+        width: root.width
+        height: 32
+        horizontalAlignment: Text.AlignHCenter
+        verticalAlignment: Text.AlignVCenter
+        text: S.NetworkService.wifiEnabled ? "No networks available" : "Wi-Fi is off"
+        color: S.Theme.base04
+        font.pixelSize: S.Theme.fontSize
+        font.family: S.Theme.fontFamily
+    }
+}

shell/applets/qmldir

@@ -8,6 +8,7 @@ GpuApplet 1.0 GpuApplet.qml
 HexWaveBackground 1.0 HexWaveBackground.qml
 MemoryApplet 1.0 MemoryApplet.qml
 MprisApplet 1.0 MprisApplet.qml
+NetworkApplet 1.0 NetworkApplet.qml
 TemperatureApplet 1.0 TemperatureApplet.qml
 VolumeApplet 1.0 VolumeApplet.qml
 # keep-sorted end

shell/modules/Bar.qml

@@ -181,7 +181,6 @@ PanelWindow {
             // Connectivity
             M.BarGroup {
                 M.NetworkModule {
-                    bar: bar
                     visible: S.Modules.network.enable
                 }
                 M.BluetoothModule {

shell/modules/NetworkModule.qml

@@ -2,6 +2,7 @@ import QtQuick
 import Quickshell
 import "." as M
 import "../services" as S
+import "../applets" as C
 
 M.BarSection {
     id: root
@@ -10,6 +11,23 @@ M.BarSection {
 
     readonly property string state: S.NetworkService.state
 
+    property bool _pinned: false
+    readonly property bool _anyHover: root._hovered || hoverPanel.panelHovered
+    readonly property bool _showPanel: _anyHover || _pinned
+
+    on_AnyHoverChanged: {
+        if (_anyHover)
+            _unpinTimer.stop();
+        else if (_pinned)
+            _unpinTimer.start();
+    }
+
+    Timer {
+        id: _unpinTimer
+        interval: 500
+        onTriggered: root._pinned = false
+    }
+
     M.BarIcon {
         icon: {
             if (root.state === "wifi")
@@ -22,23 +40,71 @@ M.BarSection {
         }
         color: root.state === "disconnected" ? S.Theme.base08 : root.accentColor
         anchors.verticalCenter: parent.verticalCenter
+        TapHandler {
+            onTapped: root._pinned = !root._pinned
+        }
     }
     M.BarLabel {
         visible: root.state === "wifi"
         label: S.NetworkService.essid
         color: root.state === "disconnected" ? S.Theme.base08 : root.accentColor
         anchors.verticalCenter: parent.verticalCenter
+        TapHandler {
+            onTapped: root._pinned = !root._pinned
+        }
     }
 
-    required property var bar
+    M.HoverPanel {
-
+        id: hoverPanel
-    readonly property bool _anyHover: root._hovered || networkMenu.panelHovered
+        showPanel: root._showPanel
-
-    M.NetworkMenu {
-        id: networkMenu
-        showPanel: root._anyHover
         screen: QsWindow.window?.screen ?? null
         anchorItem: root
         accentColor: root.accentColor
+        panelNamespace: "nova-network"
+        panelTitle: "Wi-Fi"
+        contentWidth: 250
+        titleActionsComponent: Component {
+            Item {
+                width: 20
+                height: 20
+
+                Text {
+                    anchors.centerIn: parent
+                    text: "\uF011"
+                    color: S.NetworkService.wifiEnabled ? hoverPanel.accentColor : S.Theme.base04
+                    font.pixelSize: S.Theme.fontSize
+                    font.family: S.Theme.iconFontFamily
+
+                    Behavior on color {
+                        ColorAnimation {
+                            duration: 100
+                        }
+                    }
+                }
+
+                HoverHandler {
+                    cursorShape: Qt.PointingHandCursor
+                }
+
+                TapHandler {
+                    onTapped: S.NetworkService.setWifi(!S.NetworkService.wifiEnabled)
+                }
+            }
+        }
+
+        onVisibleChanged: if (visible)
+            S.NetworkService.refresh()
+
+        Connections {
+            target: S.NetworkService
+            function onNetworksChanged() {
+                hoverPanel.keepOpen(500);
+            }
+        }
+
+        C.NetworkApplet {
+            width: hoverPanel.contentWidth
+            accentColor: root.accentColor
+        }
     }
 }

shell/modules/qmldir

@@ -19,7 +19,6 @@ HoverPanel 1.0 HoverPanel.qml
 IdleInhibitorModule 1.0 IdleInhibitorModule.qml
 MemoryModule 1.0 MemoryModule.qml
 MprisModule 1.0 MprisModule.qml
-NetworkMenu 1.0 NetworkMenu.qml
 NetworkModule 1.0 NetworkModule.qml
 NotifCard 1.0 NotifCard.qml
 NotifCenter 1.0 NotifCenter.qml